wugSpace: The WhatsUp Gold Community

Script Library

This is a public Media Gallery public RSS

Active Monitor

Cisco VPN active monitor

Active Monitor posted 12/11/09 by Neil Behagg

858 Views

Name:

Cisco VPN active monitor

Description:

This script is for monitoring Cisco VPN tunnels using SNMP. To use it, create an active monitor using vb script and paste the code in. On the device you wish to monitor, create a new interface from the device properties general page, and give the new interface the IP address of the VPN endpoint. Then, assign the active monitor to that device and set it to use the interface you have just created.

The script works by reading the new interface IP address and then looking for this IP address in the Cisco SNMP OID 1.3.6.1.4.1.9.9.171.1.2.3.1.7. This OID lists the endpoints of all active VPN tunnels, and when a tunnel is destroyed the entry is removed. Hence the active monitor will show as up if the IP address you specified is found, and down if it is not. I have so far tested this and am using it on two separate Cisco routers (and WUG 14.1), any problems or comments please let me know!

Language:

VB Script

Code:

Option Explicit

Dim strIPEndPoint
Dim intResult, strResult
Dim strOID, objSNMP, objSNMPResult, objComResult, strValue
Dim boolError, boolSNMPErr, strError, strMaxOID, nDeviceID
Dim intCharPos, intLength, strOctet1, strOctet2, strOctet3, strOctet4

'**********************************************************
'     INSTRUCTIONS
'
' Configure an additional interface in device properties 
' with the IP address as the VPN end point IP address.
'
' Set this monitor to poll using the newly set up interface.
'
'**********************************************************

strIPEndPoint = Context.GetProperty("Address")

'Modify the IP address to have leading zeros where required
'Octet 1
intCharPos = InStr (strIPEndPoint, ".")
intLength = Len (strIPEndPoint)
strOctet1 = Left(strIPEndPoint, intCharPos - 1)
strIPEndPoint = Mid (strIPEndPoint, intCharPos + 1)

'Octet 2
intCharPos = InStr (strIPEndPoint, ".")
intLength = Len (strIPEndPoint)
strOctet2 = Left(strIPEndPoint, intCharPos - 1)
strIPEndPoint = Mid (strIPEndPoint, intCharPos + 1)

'Octet 3
intCharPos = InStr (strIPEndPoint, ".")
intLength = Len (strIPEndPoint)
strOctet3 = Left(strIPEndPoint, intCharPos - 1)
strIPEndPoint = Mid (strIPEndPoint, intCharPos + 1)

'Octet 4
strOctet4 = strIPEndPoint

'Check lengths and append leading 0s
While Len(strOctet1) < 3
    strOctet1 = "0" & strOctet1
Wend
While Len(strOctet2) < 3
    strOctet2 = "0" & strOctet2
Wend
While Len(strOctet3) < 3
    strOctet3 = "0" & strOctet3
Wend
While Len(strOctet4) < 3
    strOctet4 = "0" & strOctet4
Wend

'Reconstruct IP address
strIPEndPoint = strOctet1 & "." & strOctet2 & "." & strOctet3 & "." & strOctet4

strError = strError & "VPN End Point is " & strIPEndPoint & chr(10)

strOID = "1.3.6.1.4.1.9.9.171.1.2.3.1.7"

set objSNMP = CreateObject("CoreAsp.SnmpRqst")
nDeviceID = Context.GetProperty("DeviceID")
set objComResult = objSNMP.Initialize(nDeviceID)
intResult = 1
boolError = False

If objComResult.Failed Then
    boolError = True
    strError = strError & "Error initialising SNMP. " & chr(10)
End If

If boolError = False Then
    strMaxOID = "1.3.6.1.4.1.9.9.171.1.2.3.1.8"
    While strOID < strMaxOID
        set strResult = objSNMP.GetNext(strOID)
        strValue = strResult.GetPayload
        strOID = strResult.GetOID
        If strOID < strMaxOID then
            If strValue = strIPEndPoint Then
                strError = strError & "VPN Tunnel detected. " & chr(10)
                intResult = 0
                strOID = strMaxOID
            End If
        End If
    Wend
    If intResult = 1 Then
        strError = strError & "VPN Tunnel NOT ACTIVE. " & chr(10)
    End If
End If

Context.SetResult intResult, strError

Set objSNMP = Nothing
Set objComResult = Nothing
Set objSNMPResult = Nothing

Disclaimer:

All scripts found on wugSpace are provided as-is with no warranty or guarantee. These scripts are not supported by Ipswitch Technical Support. If you have a problem with this script, please ask any questions in the comments.

Be the first to rate this
|
Sign in to rate this