wugSpace: The WhatsUp Gold Community

Script Library

This is a public Media Gallery publicRSS
Action

SMS using Internet Provider
Action posted 11/2/09 by James Hogbin
1144 Views
Name:
SMS using Internet Provider
Description:
A script that uses an internet provider (ASPSMS) to send SMS messages.
Language:
VB Script
Code:
strMessage ="%Device.ActiveMonitorDownNames" & " is " & "%Device.State" & " on " & "%Device.Type" & ": " & "%Device.HostName" & " [" & "%Device.Address" & "]."
strMessage = strMessage & " This SMS was sent on: " & now()

'Sending log message to the WhatsUp Event Viewer
Context.LogMessage "Checking ActionTypeName=" & Context.GetProperty("ActionTypeName")
Context.NotifyProgress "Checking ActionTypeName=" + Context.GetProperty("ActionTypeName")


Set SMS = New ASPSMS_XML
    SMS.Userkey      = "XXXXXXXXXXXX"
    SMS.Password     = "password"
    SMS.AddRecipient "+449999999991", "0001"
    SMS.AddRecipient "+449999999992", "0002"
    SMS.AddRecipient "+449999999993", "0003"
    SMS.AddRecipient "+449999999994", "0004"
    SMS.AddRecipient "+449999999995", "0005"
    SMS.Originator   = "WhatsUp"
    SMS.MessageData  = strMessage
    SMS.SendTextMessage
Set SMS = Nothing

'Set the result code of the check (0=Success, 1=Error)
Context.SetResult 0, "No error"

Class ASPSMS_XML
      'Version 1.1
    '18.05.2005 by aspsms.com
   
  '--- Private Member Variables --------------------------

    Private m_nRandomNumber

    Private m_sXmlInterfaceUrl

    Private m_sXmlLog

    Private m_nErrorCode
    Private m_sErrorDescription

    Private m_sPasswordFileLocation
    Private m_sUserkey
    Private m_sPassword

    Private m_sPhoneNumber
    Private m_sXmlRecipients
    Private m_sXmlTransRefNumbers

    Private m_sOriginator

    Private m_bFlashingSMS
    Private m_bBlinkingSMS
    Private m_nReplaceMessage

    Private m_sXser
    Private m_sMessageData

    Private m_nMCC
    Private m_nMNC

    Private m_sURLBinaryFile

    Private m_sVCardName
    Private m_sVCardPhoneNumber

    Private m_sTimeZone
    Private m_sDeferredDeliveryTime

    Private m_nLifeTime

    Private m_sURLBufferedMessageNotification
    Private m_sURLDeliveryNotification
    Private m_sURLNonDeliveryNotification

    Private m_nNotificationInquirySettingsFormat
    Private m_sNotificationInquirySettingsSeparator

    Private m_sWAPPushDescription
    Private m_sWAPPushURL

    Private oXmlDocRequest
    Private oXmlDocResponse
    Private oXmlHttp

    '--- Event Handlers ------------------------------------

    Private Sub Class_Initialize()
        '2004 by aspsms.com

        Randomize
        m_nRandomNumber = Int(Rnd()*2)+1

        If m_nRandomNumber/2 = Int(m_nRandomNumber/2) Then
            m_sXmlInterfaceUrl  = "http://xml1.aspsms.com:5061/xmlsvr.asp"
        Else
            m_sXmlInterfaceUrl  = "http://xml2.aspsms.com:5061/xmlsvr.asp"
        End If

        m_sXmlLog = m_sXmlLog & vbCr & m_sXmlInterfaceUrl & vbCr

        'create XML objects
        Set oXmlDocRequest  = CreateObject("MSXML2.DOMDocument")
        Set oXmlHttp        = CreateObject("MSXML2.XMLHTTP")
        Set oXmlDocResponse = CreateObject("MSXML2.DOMDocument")

    End Sub

    Private Sub Class_Terminate()
        '2004 by aspsms.com

        'destroy XML objects
        Set oXmlDocResponse = Nothing
        Set oXmlHttp        = Nothing
        Set oXmlDocRequest  = Nothing

    End Sub


    '--- Property Lets -------------------------------------

    Public Property Let PasswordFileLocation(sPasswordFileLocation)
        m_sPasswordFileLocation = sPasswordFileLocation
    End Property

    Public Property Let Userkey(sUserkey)
        m_sUserkey = sUserkey
    End Property

    Public Property Let Password(sPassword)
        m_sPassword = sPassword
    End Property

    Public Property Let Originator(sOriginator)
        m_sOriginator = sOriginator
    End Property

    Public Property Let FlashingSMS(bFlashingSMS)
        m_bFlashingSMS = bFlashingSMS
    End Property

    Public Property Let BlinkingSMS(bBlinkingSMS)
        m_bBlinkingSMS = bBlinkingSMS
    End Property

    Public Property Let ReplaceMessage(nReplaceMessage)
        m_nReplaceMessage = nReplaceMessage
    End Property

    Public Property Let MCC(nMCC)
        m_nMCC = nMCC
    End Property

    Public Property Let MNC(nMNC)
        m_nMNC = nMNC
    End Property

    Public Property Let XSer(sXSer)
        m_sXSer = sXSer
    End Property

    Public Property Let MessageData(sMessageData)
        m_sMessageData = sMessageData
    End Property

    Public Property Let TimeZone(sTimeZone)
        m_sTimeZone = sTimeZone
    End Property

    Public Property Let DeferredDeliveryTime(sDeferredDeliveryTime)
        m_sDeferredDeliveryTime = sDeferredDeliveryTime
    End Property

    Public Property Let LifeTime(nLifeTime)
        m_nLifeTime = nLifeTime
    End Property

    Public Property Let URLBufferedMessageNotification(sURLBufferedMessageNotification)
        m_sURLBufferedMessageNotification = sURLBufferedMessageNotification
    End Property

    Public Property Let URLDeliveryNotification(sURLDeliveryNotification)
        m_sURLDeliveryNotification = sURLDeliveryNotification
    End Property

    Public Property Let URLNonDeliveryNotification(sURLNonDeliveryNotification)
        m_sURLNonDeliveryNotification = sURLNonDeliveryNotification
    End Property

    Public Property Let NotificationInquirySettingsFormat(nNotificationInquirySettingsFormat)
        m_nNotificationInquirySettingsFormat = nNotificationInquirySettingsFormat
    End Property

    Public Property Let NotificationInquirySettingsSeparator(sNotificationInquirySettingsSeparator)
        m_sNotificationInquirySettingsSeparator = sNotificationInquirySettingsSeparator
    End Property

    Public Property Let WAPPushDescription(sWAPPushDescription)
        m_sWAPPushDescription = sWAPPushDescription
    End Property

    Public Property Let WAPPushURL(sWAPPushURL)
        m_sWAPPushURL = sWAPPushURL
    End Property


    '--- Property Gets -------------------------------------

    Public Property Get XmlLog()
         XmlLog = m_sXmlLog
    End Property

    Public Property Get ErrorCode()
         ErrorCode = m_nErrorCode
    End Property

    Public Property Get ErrorDescription()
         ErrorDescription = m_sErrorDescription
    End Property

    '--- Private Methods -----------------------------------

    Private Function isoEncode(sString)
        '2004 by aspsms.com

        Dim i
        Dim sChar

        For i = 1 To Len(sString)

            sChar = Mid(sString, i, 1)

            Select Case True

                'character must be encoded
                '&, <, >, chr(128)-chr(255)
                Case Asc(sChar) = 38 OR _
                     Asc(sChar) = 60 OR _
                     Asc(sChar) = 62 OR _
                     (Asc(sChar) >= 128 AND Asc(sChar) <= 255)
                isoEncode = isoEncode & "&#" & Asc(sChar) & ";"

                'character must not be encoded
                Case Else
                isoEncode = isoEncode & sChar

            End Select

        Next 'i

    End Function

    Private Sub talkToXmlInterfaceForSend(byVal sXml)
        '2004 by aspsms.com

        Dim sResponseXml

        oXmlDocRequest.SetProperty "ServerHTTPRequest", False
        oXmlDocRequest.Async = False
        oXmlDocRequest.LoadXML(sXml)

        If oXmlDocRequest.ParseError = 0 Then
            oXmlHttp.Open "POST", m_sXmlInterfaceUrl, False
            oXmlHttp.Send oXmlDocRequest.xml
            sResponseXml = oXmlHttp.ResponseXML.xml

            m_sXmlLog = m_sXmlLog & vbCr & sResponseXml & vbCr

            oXmlDocResponse.setProperty "ServerHTTPRequest", True
            oXmlDocResponse.async = False
            oXmlDocResponse.LoadXML sResponseXml

            m_nErrorCode = CInt(oXmlDocResponse.getElementsByTagName("ErrorCode").item(0).text)
            m_sErrorDescription = oXmlDocResponse.getElementsByTagName("ErrorDescription").item(0).text

        Else
            m_nErrorCode = 99
            m_sErrorDescription = "XML ParseError"
        End If

    End Sub


    Private Function setTimeZoneDeferredDeliveryTime()
        '2004 by aspsms.com
        If m_sTimeZone <> "" Then
            setTimeZoneDeferredDeliveryTime = setTimeZoneDeferredDeliveryTime & "  <TimeZone>" & m_sTimeZone & "</TimeZone>" & vbCr
        End If
        If m_sDeferredDeliveryTime <> "" Then
            setTimeZoneDeferredDeliveryTime = setTimeZoneDeferredDeliveryTime & "  <DeferredDeliveryTime>" & m_sDeferredDeliveryTime & "</DeferredDeliveryTime>" & vbCr
        End If
    End Function

    Private Function setLifeTime()
        '2005 by aspsms.com
        If m_nLifeTime <> "" Then
            setLifeTime = setLifeTime & "  <LifeTime>" & m_nLifeTime & "</LifeTime>" & vbCr
        End If
    End Function


    Private Function setNotificationURLs()
        '2004 by aspsms.com
        If m_sURLBufferedMessageNotification <> "" Then
            setNotificationURLs = setNotificationURLs & "  <URLBufferedMessageNotification>" & isoEncode(m_sURLBufferedMessageNotification) & "</URLBufferedMessageNotification>" & vbCr
        End If
        If m_sURLDeliveryNotification <> "" Then
            setNotificationURLs = setNotificationURLs & "  <URLDeliveryNotification>" & isoEncode(m_sURLDeliveryNotification) & "</URLDeliveryNotification>" & vbCr
        End If
        If m_sURLNonDeliveryNotification <> "" Then
            setNotificationURLs = setNotificationURLs & "  <URLNonDeliveryNotification>" & isoEncode(m_sURLNonDeliveryNotification) & "</URLNonDeliveryNotification>" & vbCr
        End If
    End Function


    Private Function setUserkeyPassword()
        '2004 by aspsms.com

        Dim sMyUserkey
        Dim sMyPassword

        Dim oFs
        Dim oF
        Dim sLine
        Dim sLineArray

        If m_sPasswordFileLocation <> "" Then
            Set oFs = Server.CreateObject("Scripting.FileSystemObject")
                If oFs.FileExists(m_sPasswordFileLocation) Then
                    Set oF = oFs.OpenTextFile(m_sPasswordFileLocation, 1)

                        '1. line (Userkey = XXXXXXXXXXXX)
                        sLine = oF.ReadLine
                        sLineArray = Split(sLine, "=")
                        sMyUserkey = Trim(sLineArray(1))

                        '2. Line (Password = XXXXXX)
                        sLine = oF.ReadLine
                        sLineArray = Split(sLine, "=")
                        sMyPassword = Trim(sLineArray(1))

                        oF.Close
                    Set oF = Nothing
                End If
            Set oFs = Nothing
        Else
            sMyUserkey  = m_sUserkey
            sMyPassword = m_sPassword
        End If

        setUserkeyPassword = setUserkeyPassword & "  <Userkey>" & isoEncode(sMyUserkey) & "</Userkey>" & vbCr
        setUserkeyPassword = setUserkeyPassword & "  <Password>" & isoEncode(sMyPassword) & "</Password>" & vbCr

    End Function


    '--- Public Methods ------------------------------------

    Public Sub AddRecipient(byVal sPhoneNumber, byVal sTransRefNumber)
        '2004 by aspsms.com
        m_sXmlRecipients = m_sXmlRecipients & "  <Recipient>" & vbCr
        m_sXmlRecipients = m_sXmlRecipients & "    <PhoneNumber>" & sPhoneNumber & "</PhoneNumber>" & vbCr
        m_sXmlRecipients = m_sXmlRecipients & "    <TransRefNumber>" & sTransRefNumber & "</TransRefNumber>" & vbCr
        m_sXmlRecipients = m_sXmlRecipients & "  </Recipient>" & vbCr
    End Sub

    Public Sub DeleteAllRecipients()
        m_sXmlRecipients = ""
    End Sub

    Public Sub AddTransRefNumberForNotificationInquiry(byVal sTransRefNumber)
        '2004 by aspsms.com
        m_sXmlTransRefNumbers = m_sXmlTransRefNumbers & "  <TransRefNumber>" & isoEncode(sTransRefNumber) & "</TransRefNumber>" & vbCr
    End Sub


    Public Sub SendTextMessage()
        '2005 by aspsms.com

        Dim sXml

               'sXml = "<?xml version=""1.0""?>" & vbCr
               sXml = "<?xml version=""1.0"" encoding=""ISO-8859-1""?>" & vbCr
        sXml = sXml & "<aspsms>" & vbCr
        sXml = sXml & setUserkeyPassword()
        sXml = sXml & m_sXmlRecipients
        sXml = sXml & "  <Originator>" & m_sOriginator & "</Originator>" & vbCr
        If bFlashingSMS Then
            sXml = sXml & "  <FlashingSMS>1</FlashingSMS>" & vbCr
        End If
        If bBlinkingSMS Then
            sXml = sXml & "  <BlinkingSMS>1</BlinkingSMS>" & vbCr
        End If
        If m_nReplaceMessage <> "" Then
            sXml = sXml & "  <ReplaceMessage>" & m_nReplaceMessage & "</ReplaceMessage>" & vbCr
        End If
        sXml = sXml & "  <MessageData>" & m_sMessageData & "</MessageData>" & vbCr
        'sXml = sXml & "  <MessageData><![CDATA[" & m_sMessageData & "]]></MessageData>" & vbCr
        sXml = sXml & setTimeZoneDeferredDeliveryTime()
        sXml = sXml & setLifeTime()
        sXml = sXml & setNotificationURLs()
        sXml = sXml & "  <Action>SendTextSMS</Action>" & vbCr
        sXml = sXml & "</aspsms>"

        m_sXmlLog = m_sXmlLog & sXml & vbCr

        Call talkToXmlInterfaceForSend(sXml)
    End Sub

    End Function



End Class
Disclaimer:
All scripts found on wugSpace are provided as-is with no warranty or guarantee. These scripts are not supported by Ipswitch Technical Support. If you have a problem with this script, please ask any questions in the comments.
Be the first to rate this
|
Sign in to rate this