wugSpace: The WhatsUp Gold Community

Script Library

This is a public Media Gallery public RSS

Active Monitor

URLMonitor 1.1 (added Soap 1.1 and 1.2 content-type...

Active Monitor posted 12/08/09 by Robert Strandberg, last edited 12/29/09

724 Views

Name:

URLMonitor 1.1 (added Soap 1.1 and 1.2 content-type support)

Description:

The URLMonitor 1.1 have the same functions as the URLMonitor 1.0 and with added support for Web-Services (SOAP).

In URLMonitor 1.1 it is possibility to make HTTP POST with content-type for SOAP version 1.1 and 1.2.

You configure if you want to use it as a Active monitor (or action),Performance monitor fetching a value or reporting responsetime.

Sometimes the posted data in SOAP can be long and contain ", below a simple example how to handle that , please note that the example below are in our setup but with specific data erased.

'////////////////////// Start the URL monitor configuration
'One row with MonitorURL for every URL to monitor
Dim strPostTemp
strPostTemp = "<soapenv:Envelope xmlns:soapenv=" & chr(34) & "http://schemas.xmlsoap.org/soap/envelope/" & chr(34) & " xmlns:ns0=" & chr(34) & "http://xmlinbox.webservices.<YourDomain.com>" & chr(34) & " xmlns:xsd=" & chr(34) & "http://www.w3.org/2001/XMLSchema" & chr(34) & " xmlns:xsi=" & chr(34) & "http://www.w3.org/2001/XMLSchema-instance" & chr(34) & "><soapenv:Body><ns0:getMessage>< ---Posted data--></ns0:getMessage></soapenv:Body></soapenv:Envelope>"

MonitorURL "http://" & Context.GetProperty("Address") & ":8080/<YourURLPath>","http://xmlinbox.webservices.serviceinterface.<YourURLPath>","SOAP12","","",strPostTemp, "<getMessageResponse>","</getMessageResponse>",0

'
'////////////// End of URL monitor configuration - No changes below are needed

Text from the URLMonitor 1.0

We use this script to monitor avalability and responsetime of our web aplications.

The most advanced example we have in production are that we simulate a user doing:(Using HTTPS)

1.Accessing the first webpage (GET)
2.Login to the application (POST)
3.Search for a specific category (POST)
4.Select a specific catagory (POST)
5.Search for a specific PDF document (GET)
6.Select a specific PDF document (POST) and extracts a dynamic link
7.Download the PDF document (10MB) (GET) by using the dynamic link in step 6
8.Logout from application (GET)
Total of 8 MonitorURL function calls, every function call control the received webpage.

Below the example above
'////////////////////// Start the URL monitor configuration
'One row with MonitorURL for every URL to monitor
MonitorURL "https://<YourDomain.com>/<YourPath1>","<Your Text Content1>","GET","","","","","",0
MonitorURL "https://<YourDomain.com>/<YourPath2>","<Your Text Content2>","POST","","","<Your Posted data1>","","",0
MonitorURL "https://<YourDomain.com>/<YourPath3>","<Your Text Content3>","POST","","","<Your Posted data2>","","",0
MonitorURL "https://<YourDomain.com>/<YourPath4>","<Your Text Content4>","POST","","","<Your Posted data3>","","",0
MonitorURL "https://<YourDomain.com>/<YourPath5>","<Your Text Content5>","GET","","","","","",0
'Find dynamic document referens
MonitorURL "https://<YourDomain.com>/<YourPath6>","<Your Text Content6>","POST","","","<Your Posted data4>","<Your static startstring before dynamic content>","<Your static endstring after dynamic content>",0
'Add dynamic document referens to URL
MonitorURL "https://<YourDomain.com>/<YourPath7>" & sstrFromHost,"<Your Text Content7>","GET","","","","","",0
MonitorURL "https://<YourDomain.com>/<YourPath8>","<Your Text Content8>","GET","","","","","",0
'////////////// End of URL monitor configuration - No changes below are needed

Language:

VB Script

Code:

'------------------------------ Function of Script 
'URLMonitor script
'Note:This script is provided "as is" with no warranty or support.
'As with many other public script this script is a combination of other scripts out there.
'With reservation for spelling and grammar.
'Version V1.1 2009-11-20/Robert Strandberg Sundsvall Sweden
'
'Main function:
'For use with Whatsup Gold to monitor web sites.
'The script can be used in three diffrent ways
'#1-As an Active monitor controling a webpage or a web service
'#2-As an Performance Monitor reporting responsetime of a webpage or a web service
'#3-As an Performance Monitor extracting values from a webpage or a web service
'
'The differens between a webpage and web service (SOAP) are the "content-type" when making a HTTP POST.
'
'The script have a log file function that can be used to logg entrys to specific file.
'If the folders (PATH) to the log file does not exist the script creates it.
'If you have same name on a scripts running as Active Monitor and Performance monitor
'on the same object they will use the same log file.
'
'It is possible to make several HTTP GET and POST to simulate a user that 
'runs a webapplication.
'Note that it have to be a "true" web application in that sense that it have to be 
'pure HTTP, no support for webpages that requires JavaScript,VBscript,Java applets,
'Active X,Flash or any other plug-in.
'The script uses WinHTTP 5.1
'For more info on WinHTTP 5.1 see
'http://msdn.microsoft.com/en-us/library/aa382925(VS.85).aspx
'
'Below is a short summary of WinHTTP 5.1
'************ Start Microsoft text 
'WinHTTP 5.1 Features
'
'The following features have been added in version 5.1 of WinHTTP:
'
'IPv6 support. 
'AutoProxy capabilities. 
'HTTP/1.0 protocol, including support for keep-alive (persistent) connections and session cookies. 
'HTTP/1.1 chunked transfer support for HTTP responses. 
'Keep-alive pooling of anonymous connections across sessions. 
'Secure Sockets Layer (SSL) functionality, including client certificates. Supported SSL protocols include the following:
'SSL 2.0, SSL 3.0, and Transport Layer Security (TLS) 1.0. 
'Support for server and proxy authentication, including integrated support for Microsoft Passport 1.4 and the 
'Negotiate/ Kerberos package. 
'Automatic handling of redirects unless suppressed. 
'Scriptable interface in addition to the API. 
'Trace utility to help troubleshoot problems. 
'A number of WinINet features are not supported in WinHTTP, including URL caching and persistent cookies, autoproxy,
'autodialing, offline support, File Transfer Protocol (FTP), and the Gopher protocol.
'************ End Microsoft text 
'
'Script function in detail:
'#1-Active Monitor
'A URL is monitored if it responds with a configurable textstring.
'When a URL is monitored its configurable if the HTTP method should be GET or POST,
' when POST the posted data is also added.
'The script supports HTTP login.
'Its also possible to extract a dynamic textstring from the reveived webpage, this text
' string can be used as a a dynamic part of the next URL to be monitored (or as a 
'variable in performance monitor).
'If the dynamic textstring couldt be found the script reports the URLMonitor to have
'failed the same way as if the received webpage dosent have the expected textstring.
'This means that with the textstring extraction the script actually makes three 
'textstring controls of ths received webpage,the first is the actual control, the 
'two following are the text before and after the dynamic textstring.
'All search of text in the received webpage is done from the beginning of the page. 
'To simplify the URLs in the script and to handle diffrent charactersets the received
' webpage are "cleaned".
'The cleaning process makes the following changes of the received webpagestring: 
'-NewLine,Carrige Return,Quotation,Horizontal and Vertical TAB are removed. 
'-Characters with ASCII 128 to 255 are replaced with character "x".
'
'#2-Performance Monitor responsetime
'When used in performance monitor the same controls as when the script are used as a 
'#1-active monitor are done plus that the script reports the resonsetime in 
'milliseconds (1000 = 1 Second) of receiving the webpage.
'If the URLMonitor fails then the script reports to whatsup that the value 
'reported is invalid.
'Its possible to use the same script as in active monitor, just change the global 
'parameter "sintTypOfMonitor" from "sintTypOfMonitor=0" to "sintTypOfMonitor=1".
'
'#3-Performance Monitor extract value
'The script makes the same control as in #2 but instead of reporting the responstime
'it converts the extracted textstring to a value and reports it to whatsup.
'If the extracted textstring is not numeric then the script reports the value 
'invalid as if the URLMonitor fails.
'When handeling values its possible to change the value separators like 
'100.000 , 100,000 or 100 000.
'
'Statement:
'I have tried to keep the code to VBScript Coding Conventions
' http://msdn.microsoft.com/en-us/library/ektke1b0(VS.85).aspx
'Since it is a script I have made extensive use of global variables to simplify
'configuration and reduce processor time.
'
'Global variabels
'The script makes use of global parameter in a effort to simplify the 
'configuration of the script.
'The variabel "sstrFromHost" contains the extracted textstring from the received
'webpage, sstrFromHost holds the latest URLMonitor that have extracted a 
'textstring (with strPreStringsstrFromHost and strPostStringsstrFromHost configured).
'To speed up the "character" cleaing process of the monitored URL the 
'sintMaxPageLengthKB variable is set, if a received webpage are longer then the
'script only control the received webpage up to the sintMaxPageLengthKB value.
'The script receives all the webpage but only clean and controll the page up
'to sintMaxPageLengthKB.
'The parameters strTextToFind,strPreStringsstrFromHost and strPostStringsstrFromHost
'in the MonitorURL function call MUST be within the sintMaxPageLengthKB range
'
'Use the Context.GetProperty("Address") if you have a monitor that can be used on
'several objects.
'Note that the Context.GetProperty("Address") only works in Whatsup mode.
'
'Global parameters
'sintScriptMode = Controls how the script report, to windows commandprompt or to whatsup
'sintScriptMode = 0 = Whatsup
'sintScriptMode <> 0 = Windows commandprompt
'
'sintTypOfMonitor = Controls if the script should run as Active Monitor or Performance Monitor
'sintTypOfMonitor = 0 = Active Monitor
'sintTypOfMonitor = 1 = Performance Monitor responsetime
'sintTypOfMonitor = 2 = Performance Monitor extract value
'
'When used to extract value from webpage set number handeling
'Example 100000 kan be express as 100.000 or 100 000 or 100.000
'For example
'strNumberSeparatorToReplace = ","
'strNewNumberSeparator = ""
'
'Character compability
'To handle different character sets only ASCII 1 to 127 is used in string.
'Ascii > 127 numbers are change to "x"
'
'Tips on how to configure the script using simple tools
'
'******** Working in Windows commandprompt
'
'Tool #1-FireFox with plug-in "Live HTTP Headers"
'This shows the HTTP GET and POST including POST-data (on HTTP and HTTPS).
'From this information you find the following:
'-Which URL to check
'-Which GET or POST method and POST data.
'-When to use HTTP login
'A more advanced tool is "FireBug"
'
'Tool #2-Microsoft script editor
'This tool have three main advantage compared to notepad.
'-It shows code,command and comments in different colors.
'-It have row,column and characther counter
'-It is aware of the MonitorURL functions parameters.
'The Microsoft script editor comes with office11/Office 2003
'You can start it from any office program, for example Excel choose Tools->Macro or you can start it direct
'with the command "PATH_TO_OFFICE11"\mse7.exe.
'
'Example on workflow to configure a script
'To start the script in windowsprompt type "cscript URLMonitor_1_0.vbs"
'
'#1 Configure the script for windowsprompt with parameter "sintScriptMode=1" in the script editor and the parameter "sintTypOfMonitor" to
'0,1 or 2 depending on your need.
'#2 Use Firefox and LiveHTTP headers to find the URL and HTTP parameters.
'#3 Configure the script in the script editor.
'#4 Start the script in a commandprompt
'#5 Find the text to monitor and if extraction of textstring find the surrounding static text.
'An alternativ to #3-#5 is to use view source in IE (not Firefox for this,I have experience problems with HTTPS) to find the text,
'remember that the script "cleans" the webpage.
'#6 Configure the script with the parameters.
'#7 Start the script again in a commandprompt, if it succeeds you have finished with the first URLMonitor.
'#8 Add a new MonitorURL line in the script and repeat step #2 to #7 until you have simulated a user.
'#9 Copy the script to whatsup and change the parameter "sintScriptMode=0".
'#10 Configuiration finished.
'
'Use the Whatsup eventviewer in debug mode (right mouse click) to see the log message.
'
'Configuration example
'Please note that the www.whatsupgold.com websites is used in the examples so that you can test that the script works,
'however use your own sites when you start making changes.
'This script examples below worked against the URL when this script was released.
'
'Check page and extract value
'sintTypOfMonitor = 0 or 1 or 2 
'MonitorURL "http://www.whatsupgold.com","<title>Network Management with Network Monitoring | Know Your Network with WhatsUp Gold</title>" ,"GET","","","","At work in over "," networks just like yours",0
'
'Version history
'V1.0 First public release
'V1.1 Added SOAP11 and SOAP12 as URLMethods to be able to make POST to webservices.
'
'------------------------------- Init of script 
Option Explicit
Public sobjWinHttp51 'WinHTTP 5.1 object
Public sintMonitorResault 'Overall URL resault
Public sintFirstErrorFlag 'Used to detect and log only the first error
Public sstrFromHost 'Extracted textstring from URL
Public sintMaxPageLengthKB 'Max length of received page in Kbyte
Dim tmResponseTimeURL 
Dim tmStartTimeURLCheck
Public sintScriptMode 'Whatsup or Windows mode
Public sintTypOfMonitor 'Active or performance monitor
Dim strNumberSeparatorToReplace 
Dim strNewNumberSeparator
Public sstrScriptName
Public sintLogMode
Public sintLogFileSizeKB
Public sstrLogFilePath
Public sstrLogTextToFile
'URL Check correct
sintMonitorResault = 0
sintFirstErrorFlag = 0
sstrFromHost = ""
sstrLogTextToFile =""
'Create object
Set sobjWinHttp51 = CreateObject("WinHttp.WinHttpRequest.5.1")
'Start timer
tmStartTimeURLCheck =Timer()
'//////////////////////// G l o b a l - C o n f i g u r a t i o n
'sintScriptMode = 0 = Whatsup
'sintScriptMode <> 0 = Windows commandprompt
sintScriptMode = 0
'sintTypOfMonitor = 0 = Active Monitor
'sintTypOfMonitor = 1 = Performance Monitor responsetime
'sintTypOfMonitor = 2 = Performance Monitor extract value
sintTypOfMonitor = 0
'When used to extract value from webpage set number handeling
'Example 100000 kan be express as 100.000 or 100 000 or 100.000
strNumberSeparatorToReplace = ","
strNewNumberSeparator = ""
'sintLogMode sets the logging mode
'sintLogMode = 0 = No logging to file (Normal Setting)
'sintLogMode = 1 = Logging overall failures to log file
'sintLogMode = 2 = Logging everything to log file
sintLogMode = 0
'Logfile path where the script stores logfiles when sintLogMode <> 0
'The logfile will have the name "sstrScriptName" + "HostName" in whatsup, when testing in windows pormpt it will be sstrScriptName string below
'The script create the log folders
sstrLogFilePath ="C:\URLMonitor\Log"
'sintLogFileSizeKB max size of logfile, if logfile reach that size loggning to file stops until
'logfile are renamed,moved or deleted
sintLogFileSizeKB = 1000
'sintMaxPageLengthKB max length of the received webpage in every MonitorURL function call.
'The script will receive all the webpage but to speed up the cleaning process a max size is recommended.
'This max size is for every separate MonitorURL function call, If you make 10 calls of MonitorURL simulating a user
'the script will only check every webpage to sintMaxPageLengthKB.
'The strTextToFind and variable sstrFromHost must be within the sintMaxPageLengthKB range
sintMaxPageLengthKB = 10
'//////////////////////// E n d - o f - G l o b a l - C o n f i g u r a t i o n
'Scriptname
'This name is used to find the specific script and host combination in the whatsup eventviewer
If sintScriptMode = 0 Then
        If sintTypOfMonitor = 1 or sintTypOfMonitor = 2 then
            sstrScriptName = Context.GetProperty("PerformanceMonitorTypeName") & "-" & Context.GetProperty("Address")
        else
            sstrScriptName = Context.GetProperty("ActiveMonitorTypeName") & "-" & Context.GetProperty("Address")
        end if
    else
        sstrScriptName = "URL Monitor 1.1 example"
end if
'////////////////////// Start the URL monitor configuration 
'One row with MonitorURL for every URL to monitor
MonitorURL "http://www.whatsupgold.com","<title>Network Management with Network Monitoring | Know Your Network with WhatsUp Gold</title>" ,"GET","","","","At work in over "," networks just like yours",0
'
'////////////// End of URL monitor configuration - No changes below are needed 
'Count responetime
tmResponseTimeURL = CLng(TrueTimer(tmStartTimeURLCheck)*1000)
'Terminate object
Set sobjWinHttp51 = Nothing

If sintTypOfMonitor = 2 Then 'Performance monitor extract value
    If IsNumeric(sstrFromHost) = True Then
        sstrFromHost=Replace(sstrFromHost,strNumberSeparatorToReplace,strNewNumberSeparator)
        sstrFromHost=CLng(sstrFromHost)
    else
        sintMonitorResault = 1
        Log("Error, Value is not numeric for script=" & sstrScriptName & " value=" & sstrFromHost)
    end if
end if

'Check overall resault
if sintMonitorResault = 0 then
    'Set the result code of the check (0=Success, 1=Error)
    'Update Whatsup
    If sintScriptMode = 0 Then
        If sintTypOfMonitor = 1 Then
            Context.SetValue tmResponseTimeURL
        end if
        If sintTypOfMonitor = 2 Then
            Context.SetValue sstrFromHost
        end if
        Context.SetResult 0, "SetResult to success for script=" & sstrScriptName
    End if
    'Log message    
    If sintTypOfMonitor = 1 Then
        Log("URLCheck for script=" & sstrScriptName & " took " & tmResponseTimeURL & " ms to complete")
    end if
    If sintTypOfMonitor = 2 Then
        Log("Converted variable for script=" & sstrScriptName & " value= " & sstrFromHost)
    end if
    Log("Completed with success for script=" & sstrScriptName & ",All URL checks have responded correctly")
else
    If sintScriptMode = 0 Then
        Context.SetResult 1, "SetResult to failure for script=" & sstrScriptName
    end if    
    Log("Completed with error for script=" & sstrScriptName & ",the overall URL checks failed")
end if
LogToFile()
'------------------------------ End Script -------------------------------------------

'************************************ Start of functions ************************************************

Function MonitorURL(strURLToCheck,strTextToFind,strURLMetod,strUserName,strUserPassword,strURLPostData,strPreStringsstrFromHost,strPostStringsstrFromHost,intDebugInfo)
'================== Parameters for every URL 
'MonitorURL strURLToCheck,strTextToFind,strURLMetod,strUserName,strUserPassword,strURLPostData,strPreStringsstrFromHost,strPostStringsstrFromHost,intDebugInfo
'strURLToCheck = URL to check
'strTextToFind = Text string to seach for in received URL
'strURLMetod = GET,POST,SOAP11 or SOAP12, When POST then strURLPostData should contain the text to POST*
'When SOAP11 or SOAP12 the HTTP method is still POST but with diffrent content-types
'Content-type on POST,SOAP11(SOAP 1.1) and SOAP12(SOAP 1.2)
'POST = application/x-www-form-urlencoded
'SOAP11 = text/xml
'SOAP12 = application/soap+xml
'strUserName = Username when URL request login
'strUserPassword = Password when URL request login
'strURLPostData = String to POST,used togeter with strURLMetod=POST
'strPreStringsstrFromHost = String before extracted textstring (variable sstrFromHost) in the received HTML page
'strPostStringsstrFromHost = String after extracted textstring (variable sstrFromHost) in received HTML page
'intDebugInfo = 0 = No debug, 0 <> = echo webpage after characther cleaing
'If an error is received from the web server and intDebugInfo <> 0 the webpage are returned before cleaning
'
'The MonitorURL function checks and reports if error.
'The sstrFromHost contains the extract textstring from the receive webpage (when PreStringsstrFromHost and strPostStringsstrFromHost are defined)
'============================================
Dim strWebPage,intActionResault
Dim intPreVarStart,intPostVarEnd
'strURLToCheck = strURLMetod GET or POST
'Sending log message to the WhatsUp Event Viewer
Log("Checking URL=" & strURLToCheck & " with string=" & strTextToFind & " POSTdata: " & strURLPostData)

strWebPage=GetDataFromURL(sobjWinHttp51,strURLToCheck,strURLMetod, strUserName,strUserPassword,strURLPostData,intActionResault)

if Len(strWebPage) > (sintMaxPageLengthKB * 1000) then 'receive Webpage > sintMaxPageLengthKB
    Log("Script=" & sstrScriptName & " strURLToCheck=" & strURLToCheck & " received a webpage that exceeds sintMaxPageLengthKB, the check will only be within the first " & sintMaxPageLengthKB & " Kbytes, actual received length was " & Len(strWebPage) & " bytes.")
    strWebpage = Left(strWebpage,sintMaxPageLengthKB * 1000)
End if

strWebPage = CleanString(strWebPage)

'If error from web server
If intActionResault = "ERROR" Then
    'Set Error
    sintMonitorResault=1
    'Set error detected
    Log(" URL Error from WinHTTP Requester 5.1")
    If sintFirstErrorFlag = 0 or intDebugInfo <> 0 Then
        Log("=== Start error message ===" & vbNewLine & strWebPage & vbNewLine & "=== End error message ===")
        sintFirstErrorFlag = 1 ' set first error detected
    end if    
    exit function
End If

If intDebugInfo <> 0 Then
    Log("========== Start of WebPage ============" & vbNewLine & strWebPage & vbNewLine & "========== End of WebPage ==============")
    End if

'Received String check
if Instr(strWebPage,strTextToFind) > 0 then
    Log("Success, "  & strURLToCheck & " returns the text=" & strTextToFind)
    else
    'Set Error
    sintMonitorResault=1
    Log("Error, "  & strURLToCheck & " failed to return the text=" & strTextToFind)
    If sintFirstErrorFlag = 0 Then 'log received string
        Log("=== Start received web page ===" & vbNewLine & strWebPage & vbNewLine & "=== End received web page ===")
        sintFirstErrorFlag = 1 ' set first error detected
    end if    
    exit function
end if
'Find variable in page
If strPreStringsstrFromHost <> "" and strPostStringsstrFromHost <> "" then
    intPreVarStart = Instr(strWebPage,strPreStringsstrFromHost)
    intPostVarEnd = Instr(strWebPage,strPostStringsstrFromHost)
    if intPreVarStart > 0 and intPostVarEnd > intPreVarStart then
        'Add the lenth of the string as starting point to fetch variable 
        intPreVarStart = intPreVarStart + Len(strPreStringsstrFromHost)
        sstrFromHost = Mid(strWebPage,intPreVarStart,intPostVarEnd-intPreVarStart)
        Log("Success for script=" & sstrScriptName & ", found variable: "  & sstrFromHost)
        else
        'Set Error
        sintMonitorResault=1
        Log("Error for script=" & sstrScriptName & ", failed to find varible between strings: " & strPreStringsstrFromHost & " and " & strPostStringsstrFromHost)
        If sintFirstErrorFlag = 0 Then 'log received string
            Log("=== Start received web page ===" & vbNewLine & strWebPage & vbNewLine & "=== End received web page ===")
            sintFirstErrorFlag = 1 ' set first error detected
        end if    
        exit function
    End if
End if
End Function

'*****************************************************

Function CleanString(strSource)
strSource=Replace(strSource,Chr(9),"") 'Horizontal Tab
strSource=Replace(strSource,Chr(10),"") 'Line Feed
strSource=Replace(strSource,Chr(11),"") 'Vertical Tab
strSource=Replace(strSource,Chr(12),"") 'Form Feed
strSource=Replace(strSource,Chr(13),"") 'Carriage Return
strSource=Replace(strSource,Chr(34),"") 'Quotation
Dim i
For i = 128 to 255 
strSource=Replace(strSource,Chr(i),"x") 'Replace all 8-bit characters
Next 
CleanString=strSource
End Function 

'******************************************************

Function GetDataFromURL(objWinHttp,strURL, strMethod, strLogin, strPassword, strPostData,ActionCode)
'strmethod have GET,POST,SOAP11 and SOAP12
'When SOAP11 or SOAP12 the HTTP method is still POST but with diffrent content-types
'Content-type on POST,SOAP11 and SOAP12
'POST = application/x-www-form-urlencoded
'SOAP11 = text/xml
'SOAP12 = application/soap+xml
'
'SOAP11 = SOAP 1.1 and SOAP12 = SOAP 1.2


  Dim lngTimeout
  Dim strUserAgentString
  Dim intSslErrorIgnoreFlags
  Dim blnEnableRedirects
  Dim blnEnableHttpsToHttpRedirects
  Dim strHostOverride
  Dim strResponseText
  Dim strContentType
  lngTimeout = 59000
  strUserAgentString = "http_requester_whatsup/1.0"
  intSslErrorIgnoreFlags = 13056 ' 13056: ignore all err, 0: accept no err
  blnEnableRedirects = True
  blnEnableHttpsToHttpRedirects = True
  strHostOverride = ""
  objWinHttp.SetTimeouts lngTimeout, lngTimeout, lngTimeout, lngTimeout
  'Set content-type
  'Rewriting strMethod to be compliant with previuos versions
  If strMethod = "POST" Then
    strContentType = "application/x-www-form-urlencoded"
  End If
  If strMethod = "SOAP11" Then
    strContentType = "text/xml"
     strMethod = "POST"
  End If
  If strMethod = "SOAP12" Then
     strContentType = "application/soap+xml"
     strMethod = "POST"
  End If
    objWinHttp.Open strMethod, strURL
  If strMethod = "POST" Then
    objWinHttp.setRequestHeader "Content-type", _
    strContentType
  End If  
  If strHostOverride <> "" Then
    objWinHttp.SetRequestHeader "Host", strHostOverride
  End If
  objWinHttp.Option(0) = strUserAgentString
  objWinHttp.Option(4) = intSslErrorIgnoreFlags
  objWinHttp.Option(6) = blnEnableRedirects
  objWinHttp.Option(12) = blnEnableHttpsToHttpRedirects
  If (strLogin <> "") And (strPassword <> "") Then
    objWinHttp.SetCredentials strLogin, strPassword, 0
  End If    
  On Error Resume Next
  objWinHttp.Send(strPostData)
  If Err.Number = 0 Then
    If objWinHttp.Status = "200" Then
      GetDataFromURL = objWinHttp.ResponseText
     ActionCode="OK"
    Else
      GetDataFromURL = "HTTP " & objWinHttp.Status & " " & _
        objWinHttp.StatusText & " " & objWinHttp.ResponseText
     ActionCode="ERROR"
    End If
  Else
    GetDataFromURL = "Error " & Err.Number & " " & Err.Source & " " & _
      Err.Description
     ActionCode="ERROR"
  End If
  On Error GoTo 0
End Function

'******************************************************

Function TrueTimer(StartTime)
'This function corrected the Timer() function "feature" of reporting time since midnight.
'Script that uses the Timer() function that runs over midnight will show wrong time.
'This script expect that the StartTime parameter contanins the Timer() values when the Time measure started.
'The script will return the corrected elapsed time over midnight.
Dim iTimer,ElapsedTime
iTimer = Timer()    'Timer() to variable for faster processing
if iTimer - StartTime < 0 then ' Measure have passed midnight.
ElapsedTime = 86400 - StartTime
TrueTimer = ElapsedTime + iTimer
    else
    TrueTimer = (iTimer - StartTime)
end if
End Function

'******************************************************

Function Log(strTextToLog)
'This Logs information to windows prompt or whatsup eventlog,it also logs to a file if logging are enable
'function reads global variable sintScriptMode and updates the sstrLogTextToFile.
If sintScriptMode = 0 Then
    Context.LogMessage strTextToLog
    else
    Wscript.Echo(strTextToLog)
end if
'Update the sstrLogTextToFile 
sstrLogTextToFile = sstrLogTextToFile & date() & " " & time() & " " & strTextToLog & vbNewLine
End Function

Function LogToFile()
'This Logs information to windows prompt or whatsup eventlog,it also logs to a file if logging are enable
'function reads global variable sintLogMode,sstrLogFilePath,sintLogFileSizeKB,sstrScriptName and sstrLogTextToFile.
'When logging to file the logging stops when the logfile reach max limit, to continue with loggning to file the
'existing logfile have to be renamed,moved or deleted.
'uses the Log() Function.

If sintLogMode <> 0 then
    Dim strLogFileName
    Dim fso
    Dim strLogFile
    Const ForAppending = 8
    strLogFileName = sstrLogFilePath & "\" & sstrScriptName & ".log"
    Set fso = CreateObject("Scripting.FileSystemObject")
    'Check if file exist
    If fso.FileExists(strLogFileName) then
        'Control size
        Set strLogFile = fso.GetFile(strLogFileName)
        'Logfile size exceeds max size
        If strLogFile.size/1000 > sintLogFileSizeKB then
            Log("Failed to write to logfile for script " & sstrScriptName & " ,file exceeds sintLogFileSizeKB value=" & sintLogFileSizeKB & " KB for logfile " & strLogFileName)
            Exit function    
            else
            'File open
            set strLogFile = fso.OpenTextFile(strLogFileName,ForAppending)
        End if
    else
        'Control if folders exist
        Dim i,strTempPath,intLoopEnd
        i = 3
        intLoopEnd = 0
        'Loop until all folders in the path are created
        Do until intLoopEnd <> 0
        'No more "\" in the string 
            If instr(i+1,sstrLogFilePath,"\",0) = 0 then 
                strTempPath = sstrLogFilePath
                intLoopEnd = 1 'all folders are extracted from string and created if nessesary
                else
                strTempPath = Mid(sstrLogFilePath,1,instr(i+1,sstrLogFilePath,"\",0))
                i = instr(i,sstrLogFilePath,"\",0)
            end if
            If fso.FolderExists(strTempPath) = False then
                Dim fsoFolder
                'Create folders
                Set fsoFolder = fso.CreateFolder(strTempPath)
                Log("Created Logfile folder " & strTempPath & " ,script " & sstrScriptName)
            end if
            i = instr(i+1,sstrLogFilePath,"\",0)
            loop    
            'create file
            Set strLogFile = fso.CreateTextFile(strLogFileName, True)
            Log("Created logfile " & strLogFileName)
    end if
        'File ready for use
        'Log level
    If sintLogMode  = 1  and sintMonitorResault = 1 or sintLogMode  >= 2 then
        strLogFile.Write(sstrLogTextToFile)
        Log("Added entry to logfile " & strLogFileName)
    end if
strLogFile.Close
End if
End Function

Disclaimer:

All scripts found on wugSpace are provided as-is with no warranty or guarantee. These scripts are not supported by Ipswitch Technical Support. If you have a problem with this script, please ask any questions in the comments.

Be the first to rate this
|
Sign in to rate this